File:Chinapop.svg

# POPULATION PYRAMID
 
scale = 1000000 # ADJUST AS NECESSARY
# The increment would better be automatic, but "set xtics" doesn't
# allow to specify start only.
increment = 10 # ADJUST THIS AS NECESSARY
 
set title "China - 2009"
 
# Plot to dummy device and retrieve the male/female population range
set term unknown
set autoscale xfix
plot "china2009.txt" using ($2/scale):1, "china2009.txt" using (-$3/scale):1
 
range_male = (GPVAL_X_MAX > -GPVAL_X_MIN) ? GPVAL_X_MAX : -GPVAL_X_MIN
range_female = range_male
central_gap = (range_male + range_female) * 0.06 # ADJUST AS NECESSARY
 
set term svg size 800,500 dynamic font "sans-serif"
 
set style data boxxyerrorbars
set style fill solid 0.25 border
 
# Y axis has no lines and tics, only labels which are shifted to bar medians
set yzeroaxis linewidth 0
set ytics axis scale 0
set ytics offset 0, second 1.8
set autoscale yfix
 
# X axis is labeled from zero onwards, with the given increment
set xtics nomirror 0,increment
set xlabel "Population (millions)"
 
set key right Right
plot [-range_female-central_gap:range_male]\
 "china2009.txt" using (0):(0):(0):($3/scale):1:($1+4.8) title "Females" linetype rgb "#FF0000"
 
# Remove Y labels, we already have them from the previous plot.
set format y ""
set key left Left reverse
 
plot [range_female:-central_gap-range_male]\
 "china2009.txt" using (0):(0):(0):($2/scale):1:($1+4.8) title "Males" linetype rgb "#0000FF"