File:Normal approximation to binomial.svg

[edit] Summary

svg version of the same png Normal_approximation_to_binomial.png file. Original author: User:MarkSweep

This vector image was created with gnuplot.

gnuplot source under GPL:

# normal (Gaussian) distribution
_ln_dnorm(x, m, s) = -0.5 * log(2*pi) - log(s) - 0.5*((x-m)*1.0/s)**2
dnorm(x, mean, sd) = exp(_ln_dnorm(x, mean, sd))
pnorm(x, mean, sd) = norm((x-mean) * 1.0/sd)

# binomial distribution
_ln_binom(x, n, p) =\
 lgamma(n+1) - lgamma(x+1) - lgamma(n-x+1) + x*log(p) + (n-x)*log(1-p)
dbinom(x, size, prob) = (x==int(x))? exp(_ln_binom(floor(x), size,  prob)) : 0
pbinom(x, size, prob) =\
 (x<0)? 0 : (x<size)? ibeta(size-floor(x), floor(x)+1, 1-prob) : 1

set terminal svg
set output "Normal approximation to binomial.svg"

set key 22,0.13

n = 48
p = 0.25
xmax = 25

set samples 50*xmax+1

plot [0:xmax] \
    dbinom(x, n, p) with impulses title "Binom(48, 0.25)", \
    dnorm(x, n*p, sqrt(n*p*(1-p))) linetype 3 title "Norm(12, 3)"

[edit] Licensing

Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License. www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

	This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
	You are free: to share – to copy, distribute and transmit the work to remix – to adapt the work Under the following conditions: attribution – You must attribute the work in the manner specified by the author or licensor (but not in any way that suggests that they endorse you or your use of the work). share alike – If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one.
	This licensing tag was added to this file as part of the GFDL licensing update.www.creativecommons.org/licenses/by-sa/3.0/CC-BY-SA-3.0Creative Commons Attribution-Share Alike 3.0 truetrue

Click on a date/time to view the file as it appeared at that time.

	Date/Time	Thumbnail	Dimensions	User	Comment
current	14:56, 21 November 2006		600 × 480 (18 KB)	Vasiliev Mihail	(svg version of the same png file. Created with gnuplot. )

• Lists of mathematics topics

The following other wikis use this file:

• Usage on de.wikipedia.org
  • Satz von Moivre-Laplace
• Usage on es.wikipedia.org
  • Distribución normal
• Usage on nl.wikipedia.org
  • Stelling van De Moivre-Laplace
• Usage on tr.wikipedia.org
  • Normal dağılım
• Usage on vi.wikipedia.org
  • Phân phối chuẩn