Skew binomial heap

Not to be confused with Skew heap.

Skew binomial heap
Type	heap
Invented	1996
Invented by	Gerth Stølting Brodal and Chris Okasaki
Time complexity in big O notation Operation Average Worst case Insert Θ(1) Θ(1) Find-min Θ(1) Delete-min O(log n) Decrease-key O(log n) Merge O(log n) Space complexity

In computer science, a skew binomial heap (or skew binomial queue) is a variant of the binomial heap that supports constant-time insertion operations in the worst case, rather than the logarithmic worst case and constant amortized time of ordinary binomial heaps. Just as binomial heaps are based on the binary number system, skew binary heaps are based on the skew binary number system.

Motivation

Binomial heaps suffer from worst case logarithmic complexity for insertion, because a carry operation may cascade, analagous to binary addition. Skew binomial heaps are based on the skew binary number system, where the $k$th digit (zero-indexed) represents $2^{k+1}-1$, instead of $2^{k}$. Digits are either 0 or 1, except the lowest non-zero digit, which may be 2. An advantage of this system is that at most one carry operation is needed. For example, 60 is represented as 11200 in skew binary (31 + 15 + 7 + 7), and adding 1 produces 12000 (31 + 15 + 15). Since the next higher digit is guaranteed not to be 2, a carry is performed at most once.

Structure

A skew binomial heap is a list of skew binomial trees, which are defined inductively:

• A skew binomial tree of rank 0 is a singleton node.
• A skew binomial tree of rank $r+1$ can be constructed in three ways.
  • A simple link links two rank $r$ trees, making one the leftmost child of the other,
  • A type A skew link links three trees, where two rank $r$ trees become the children of a rank 0 tree,
  • A type B skew link links three trees, where a rank 0 tree and rank $r$ tree become the leftmost children of another rank $r$ tree.

When performing any link, the tree with the smallest key always becomes the root. The following OCaml code demonstrates the linking operations:

type 'a heap = 'a tree list
 and 'a tree = Tree of 'a * int * 'a tree list
 
let rank (Tree (_, r, _)) = r

let simple_link (Tree (k1, r, c1) as t1) (Tree (k2, r, c2) as t2) =
  if k1 <= k2 then
    Tree (k1, r + 1, t2 :: c1)
  else
    Tree (k2, r + 1, t1 :: c2)
    
let skew_link k1 (Tree (k2, r, c2) as t2) (Tree (k3, r, c3) as t3) =
  if k1 <= k2 && k1 <= k3 then (* type A *)
    Tree (k1, r + 1, [t2; t3])
  else                         (* type B *)
    let t1 = Tree (k1, 0, []) in
    if k2 <= k3 then
      Tree (k2, r + 1, t1 :: t3 :: c2)
    else
      Tree (k3, r + 1, t1 :: t2 :: c3)

Additionally, we impose the invariant that there may be only one tree of each rank, except the lowest rank which may have up to two.

From these properties, it can be deduced that a skew binomial tree of rank $r$ has between $r$ and $2r$ children. The number of nodes in a skew binomial tree $t$ of rank $r$ is also bounded by $2^{r}\leq |t|\leq 2^{r+1}-1$. Since trees of the same rank may have different numbers of nodes, there may be more than one way to distribute the ranks in the heap.

These constructions may be seen as a generalisation of binary trees and binomial trees. A skew binomial tree constructed using only simple links is an ordinary binomial tree, and using only type A skew links results in a perfectly balanced binary tree.

Operations

Find-min

Search the list of roots to find the node containing the minimum key. This takes $O(\log n)$ time.

In an imperative setting, one can maintain a pointer to the root containing the minimum key, allowing access in $O(1)$ time. This pointer must be updated after every operation, adding only a constant overhead in time complexity.

In a functional setting without random access to nodes, one can instead represent the heap as a single tree with skew binomial trees as its children. The root of this tree is the minimum of the heap, allowing $O(1)$ access. Note that this tree will not necessarily be a skew binomial tree itself. The other operations must be modified to deal with this single tree. This concept of a global root is used in the optimizations described below, albeit slightly differently.

Merge

To merge two skew binomial heaps together, first eliminate any duplicate rank trees in each heap by performing simple links. Then, merge the heaps in the same fashion as ordinary binomial heaps, which is similar to binary addition. Trees with the same ranks are linked with a simple link, and a 'carry' tree is passed upwards if necessary. Because the rank of trees in each heap is now unique, at most three trees of the same rank are be considered, which is sufficient to establish a $O(\log n)$ bound.

let rec unique = function
  | t1 :: t2 :: ts when rank t1 = rank t2 ->
    unique (simple_link t1 t2 :: ts)
  | ts -> ts

let rec merge_uniq h1 h2 = match h1, h2 with
  | h1, [] -> h1
  | [], h2 -> h2
  | t1 :: ts1, t2 :: ts2 ->
    if rank t1 < rank t2 then
      t1 :: merge_uniq ts1 h2
    else if rank t1 > rank t2 then
      t2 :: merge_uniq h1 ts2
    else
      unique (simple_link t1 t2 :: merge_uniq ts1 ts2)
  
let merge h1 h2 = merge_uniq (unique h1) (unique h2)

Insert

Create a skew binomial tree of rank 0 (a singleton node), containing the key to be inserted. The smallest two trees in the heap are then considered:

• If they are both of rank $r$, then perform a skew link with these two trees and the singleton node. The resulting tree is of rank $r+1$. Since there can only have been at most one rank $r+1$ tree in the original heap, the invariant is preserved.
• If they are of different ranks, simply add the rank 0 tree to the front of the list of roots. Since the list of roots did not have duplicate rank trees before, the invariant is not violated, as there will be at most two rank 0 trees after.

As up to one link is performed, this operation executes in worst case $O(1)$ time, improving on the binomial heap which relies on amortized analysis for its $O(1)$ bound, with a worst case of $O(\log n)$.

let insert k = function
  | t2 :: t3 :: ts when rank t2 = rank t3 -> skew_link k t2 t3 :: ts
  | ts -> Tree (k, 0, []) :: ts

Delete-min

Find and discard the node containing the minimum key. Divide its children into two groups, those with rank 0, and those with rank > 0. Note that there may be more than two children with rank 0, due to skew links. The children whose rank > 0 form a valid skew binomial heap, as they are already ordered, and have no duplicates. Merging these children into the heap takes $O(\log n)$ time. Afterwards, reinsert each of the rank 0 children into the heap at a cost of $O(1)$ each. The total time required is $O(\log n)$.

Decrease-key

This operation is unchanged from binomial heaps. Decreasing the key of a node may cause it to be smaller than its parent. Repeatedly exchange it with its parent until the minimum-heap property is satisfied, at a cost of $O(\log n)$ time complexity. This operation requires a pointer to the node containing the key in question, and easiest done in an imperative setting.

Optimizations

Brodal and Okasaki showed how the find-min and merge operations can be reduced to $O(1)$ by applying the 'bootstrapping' technique of Buchsbaum and Tarjan.

Let the type of a primitive skew binomial heap containing elements of type $\alpha$ be $H_{\alpha }$. Instead of the forest of trees representation described above, we mainintain a single tree with a global root as its minimum.

Let the type of a rooted skew binomial heap be

$R_{\alpha }=\alpha \times H_{R_{\alpha }}$,

that is, a pair containing an element of type $\alpha$ and a primitive heap of rooted heaps.

Finally, we define the type of a bootstrapped heap as

$B_{\alpha }=\{\mathrm {Empty} \}+R_{\alpha }$

which permits empty heaps.

The operations on this bootstrapped heap are redefined accordingly. In the following OCaml code, let the prime symbol denote operations for bootstrapped heaps.

type 'a bootstrapped =
  | Empty
  | Root of 'a rooted

let find_min' (Root (k, h)) = k

let merge' bh1 bh2 = match bh1, bh2 with
  | _, Empty -> bh1
  | Empty, _ -> bh2
  | Root (k1, h1), Root (k2, h2) ->
    if k1 <= k2 then
      Root (k1, insert bh2 h1)
    else
      Root (k2, insert bh1 h2)

let insert' k h = merge' (Root(k, [])) h

let delete_min' (Root (x, h)) =
  let Root (y, h1) = find_min h in
  let h2 = delete_min h in
  Root (y, merge h1 h2)

The new merge operation uses only insert operations on primitive heaps, thus, it executes in $O(1)$ time. This technique can be applied to any priority queue with constant time insertion, and logarithmic merging.

Summary of running times

Here are time complexities of various heap data structures. Function names assume a min-heap. For the meaning of "O(f)" and "Θ(f)" see Big O notation.

Operation	find-min	delete-min	insert	decrease-key	meld
Binary	Θ(1)	Θ(log n)	O(log n)	O(log n)	Θ(n)
Leftist	Θ(1)	Θ(log n)	Θ(log n)	O(log n)	Θ(log n)
Binomial	Θ(1)	Θ(log n)	Θ(1)	Θ(log n)	O(log n)
Skew binomial	Θ(1)	Θ(log n)	Θ(1)	Θ(log n)	O(log n)
Pairing	Θ(1)	O(log n)	Θ(1)	o(log n)	Θ(1)
Rank-pairing	Θ(1)	O(log n)	Θ(1)	Θ(1)	Θ(1)
Fibonacci	Θ(1)	O(log n)	Θ(1)	Θ(1)	Θ(1)
Strict Fibonacci	Θ(1)	O(log n)	Θ(1)	Θ(1)	Θ(1)
Brodal	Θ(1)	O(log n)	Θ(1)	Θ(1)	Θ(1)
2–3 heap	O(log n)	O(log n)	O(log n)	Θ(1)	?