File:Energiemix Deutschland.svg

Summary

Licensing

I, the copyright holder of this work, hereby publish it under the following license:

	This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
	You are free: to share – to copy, distribute and transmit the work to remix – to adapt the work Under the following conditions: attribution – You must attribute the work in the manner specified by the author or licensor (but not in any way that suggests that they endorse you or your use of the work). share alike – If you alter, transform, or build upon this work, you may distribute the resulting work only under the same or similar license to this one. https://creativecommons.org/licenses/by-sa/3.0 CC BY-SA 3.0 Creative Commons Attribution-Share Alike 3.0 truetrue

Gnuplot script to generate this plot

iThe source code of this SVG is valid.

This plot was created with Gnuplot:

set term svg size 800,400 font "Linux Biolinum, DejaVu Sans, Arial, 13"
set output "Energiemix_Deutschland.svg"
set samples 1001
 
set title "Bruttostromerzeugung in Deutschland nach Energieträgern 1990 – 2017 in Prozent" offset 8.0, -0.5
set key invert reverse center right Left outside samplen 1
set key autotitle columnheader
set tmargin 2.0
set bmargin 2.4
set lmargin 4.5
 
set yrange [0:100]
set ytics 10
 
set auto x
set xtics rotate by -90 offset -1.2, 0.3
 
set style data histograms
set style histogram rowstacked
set style fill solid border 0
set boxwidth 0.9
 
set cbrange [0:10]
unset colorbox

set palette defined ( 0 '#9E9E9E', \
                      1 '#06787A', \
                      2 '#966018', \
                      3 '#000000', \
                      4 '#440055', \
                      5 '#FF0000', \
                      6 '#F3FF0A', \
                      7 '#B5BAFF', \
                      8 '#04B404', \
                      9 '#58FA58', \
                     10 '#5151F5')

set datafile separator ','
plot 'energiemix_de.csv' using 2:xtic(1) lc palette cb 0, for [i=3:12] '' using i lc palette cb i-2

Raw data (energiemix_de.csv)

Energieträger,Übrige,Mineralölprodukte,Braunkohle,Steinkohle,Kernenergie,Erdgas,Photovoltaik,Windkraft,Biomasse,Hausmüll,Wasserkraft
1990,3.5,2.0,31.1,25.6,27.7,6.5,0.0,0.0,0.0,0.0,3.6
1991,3.0,2.7,29.3,27.7,27.3,6.7,0.0,0.0,0.1,0.2,2.9
1992,3.0,2.5,28.7,26.4,29.5,6.1,0.0,0.1,0.1,0.2,3.5
1993,3.0,1.9,28.0,27.7,29.1,6.2,0.0,0.1,0.1,0.2,3.6
1994,3.3,1.9,27.6,27.4,28.6,6.8,0.0,0.2,0.1,0.2,3.8
1995,3.3,1.7,26.6,27.4,28.7,7.7,0.0,0.3,0.1,0.2,4.0
1996,3.1,1.5,26.1,27.6,29.2,8.3,0.0,0.4,0.1,0.2,3.4
1997,3.2,1.3,25.7,25.9,30.8,8.7,0.0,0.5,0.2,0.3,3.4
1998,3.4,1.2,25.0,27.5,29.0,9.1,0.0,0.8,0.2,0.3,3.4
1999,3.6,1.1,24.4,25.7,30.6,9.3,0.0,1.0,0.2,0.3,3.7
2000,3.9,1.0,25.7,24.8,29.4,8.5,0.0,1.6,0.3,0.3,4.3
2001,3.6,1.0,26.4,23.6,29.2,9.5,0.0,1.8,0.6,0.3,4.0
2002,3.1,1.5,26.9,22.9,28.1,9.6,0.0,2.7,0.8,0.3,4.0
2003,3.3,1.7,26.0,24.1,27.1,10.3,0.0,3.1,1.1,0.4,2.9
2004,3.4,1.7,25.6,22.8,27.1,10.2,0.1,4.1,1.3,0.4,3.3
2005,3.9,1.9,24.8,21.5,26.2,11.7,0.2,4.4,1.8,0.5,3.1
2006,4.0,1.7,23.6,21.6,26.2,11.8,0.3,4.8,2.3,0.6,3.1
2007,4.2,1.6,24.2,22.2,21.9,12.2,0.5,6.2,3.1,0.7,3.3
2008,3.9,1.5,23.5,19.4,23.2,13.9,0.7,6.3,3.6,0.7,3.2
2009,3.6,1.7,24.4,18.1,22.6,13.6,1.1,6.5,4.4,0.7,3.2
2010,4.2,1.4,23.0,18.5,22.2,14.1,1.8,6.0,4.7,0.7,3.3
2011,4.2,1.2,24.5,18.3,17.6,14.0,3.2,8.0,5.3,0.8,2.9
2012,4.1,1.2,25.5,18.5,15.8,12.1,4.2,8.0,6.3,0.8,3.5
2013,4.1,1.1,25.2,19.9,15.2,10.6,4.9,8.1,6.5,0.8,3.6
2014,4.3,0.9,24.9,18.9,15.5,9.7,5.7,9.1,6.7,1.0,3.1
2015,4.1,1.0,23.9,18.2,14.2,9.6,6.0,12.3,6.9,0.9,2.9
2016,4.3,0.9,23.1,17.2,13.1,12.4,5.9,11.9,7.0,0.9,3.2
2017,4.3,0.9,22.6,14.4,11.6,13.1,6.1,16.1,7.0,0.9,3.0

Source: Arbeitsgemeinschaft Energiebilanzen e.V.: Bruttostromerzeugung in Deutschland ab 1990 nach Energieträgern. Percentages recalculated to avoid rounding problems

Translated versions