LFE (programming language)

From Wikipedia, the free encyclopedia
Jump to: navigation, search
LFE
LFE (Lisp Flavored Erlang) Logo.png
Paradigm multi-paradigm: concurrent, functional
Designed by Robert Virding
Developer Robert Virding
First appeared 2008
Stable release
v1.1.1 / 19 June 2016 (2016-06-19)
Typing discipline dynamic, strong
License Apache License 2.0
Filename extensions .lfe .hrl
Website lfe.io
Influenced by
Erlang, Common Lisp, MACLISP, Scheme, Elixir, Clojure, Hy
Influenced
Joxa, Concurrent Schemer

LFE (Lisp Flavored Erlang) is a functional, concurrent, general-purpose programming language and Lisp dialect built on top of Core Erlang and the Erlang Virtual Machine (BEAM). LFE builds on top of Erlang in order to provide a Lisp syntax for writing distributed, fault-tolerant, soft real-time, non-stop applications. LFE also extends Erlang to support meta-programming with Lisp macros and an improved developer experience with a feature-rich REPL.[1] LFE is actively supported on all recent releases of Erlang; the oldest version of Erlang supported is R14.

History[edit]

Initial release[edit]

Initial work on LFE began in 2007, when Robert Virding started creating a prototype of Lisp running on Erlang.[2] This work was focused primarily on parsing and exploring what an implementation might look like; no version control system was being used at the time, so tracking exact initial dates is somewhat problematic.[2]

Robert Virding announced the first release of LFE on the "Erlang Questions" mail list in March 2008.[3] This release of LFE was very limited: it did not handle recursive letrecs, binarys, receive, or try; it also did not support a Lisp shell.[4]

Initial development of LFE was done with version R12B-0 of Erlang[5] on a Dell XPS laptop.[4]

Motivation[edit]

Robert Virding has stated that there were a number of reasons why he started the LFE programming language:.[2]

  • He had previous experience programming in Lisp.
  • Given his previous experience, he was interested in implementing his own Lisp.
  • In particular, he wanted to implement a Lisp in Erlang: not only was he curious to see how it would run on and integrate with Erlang, he wanted to see what it would look like.
  • Since helping to create the Erlang programming language, he had had the goal of making a Lisp which was specifically designed for running on the BEAM and able to fully interact with Erlang/OTP.
  • He wanted to experiment with compiling another language on top of Erlang. As such, he saw LFE as a means of exploring this by generating Core Erlang and plugging it into the backend of the Erlang compiler.
  • He was not working with programming or Erlang at the time, so was looking for some interesting programming projects that were not too large to do in his spare time.
  • He likes implementing languages.
  • He also thought it would be a fun problem to solve, as a solution would have many parts and the problem space was quite open-ended.

Features[edit]

Syntax and semantics[edit]

Symbolic expressions (S-expressions)[edit]

Like Lisp, LFE is an expression-oriented language. Unlike non-homoiconic programming languages, Lisps make no or little syntactic distinction between "expressions" and "statements": all code and data are written as expressions. LFE brought homoiconicity to the Erlang VM.

Lists[edit]

In LFE, the list data type is written with its elements separated by whitespace, and surrounded by parentheses. For example, (list 1 2 'foo) is a list whose elements are the integers 1 and 2, and the atom foo. These values are implicitly typed: they are respectively two integers and a Lisp-specific data type called a "symbolic atom", and do not have to be declared as such.

As seen in the example above, LFE expressions are written as lists, using prefix notation. The first element in the list is the name of a form, i.e., a function, operator, macro, or operator. The remainder of the list are the arguments.

Operators[edit]

The LFE/Erlang operators are used in the same way. The expression

 (* (+ 1 2 3 4 5 6) 2)

evaluates to 42. Unlike functions in Erlang and LFE, arithmetic operators in Lisp are variadic (or n-ary), able to take any number of arguments.

Lambda expressions and function definition[edit]

LFE has lambda, just like Common Lisp. It also, however, has lambda-match to account for Erlang's pattern-matching capabilities in anonymous function calls.

Erlang idioms in LFE[edit]

This section does not represent a complete comparison between Erlang and LFE, but should give a taste.

Pattern matching[edit]

Erlang:

      1> {Len,Status,Msg} = {8,ok,"Trillian"}.
      {8,ok,"Trillian"}
      2> Msg.
      "Trillian"

LFE:

      > (set (tuple len status msg) #(8 ok "Trillian"))
      #(8 ok "Trillian")
      > msg
      "Trillian"

List comprehensions[edit]

Erlang:

      1> [trunc(math:pow(3,X)) || X <- [0,1,2,3]].
      [1,3,9,27]

LFE:

      > (list-comp
          ((<- x '(0 1 2 3)))
          (trunc (math:pow 3 x)))
      (1 3 9 27)

Or idiomatic functional style:

      > (lists:map
          (lambda (x) (trunc (math:pow 3 x)))
          '(0 1 2 3))
      (1 3 9 27)

Guards[edit]

Erlang:

      right_number(X) when X == 42; X == 276709 ->
      true;
      right_number(_) ->
      false.

LFE:

      (defun right-number?
        ((x) (when (orelse (== x 42) (== x 276709)))
          'true)
        ((_) 'false))

cons'ing in function heads[edit]

Erlang:

      sum(L) -> sum(L,0).
      sum([], Total) -> Total;
      sum([H|T], Total) -> sum(T, H+Total).

LFE:

      (defun sum (l) (sum l 0))
      (defun sum
        (('() total) total)
        (((cons h t) total) (sum t (+ h total))))

or using a ``cons`` literal instead of the constructor form:

      (defun sum (l) (sum l 0))
      (defun sum
        (('() total) total)
        ((`(,h . ,t) total) (sum t (+ h total))))

Matching records in function heads[edit]

Erlang:

handle_info(ping, #state {remote_pid = undefined} = State) ->
    gen_server:cast(self(), ping),
    {noreply, State};
handle_info(ping, State) ->
    {noreply, State};

LFE:

(defun handle_info
  (('ping (= (match-state remote-pid 'undefined) state))
    (gen_server:cast (self) 'ping)
    `#(noreply ,state))
  (('ping state)
   `#(noreply ,state)))

Receiving messages[edit]

Erlang:

      universal_server() ->
          receive
              {become, Func} ->
                  Func()
          end.

LFE:

      (defun universal-server ()
        (receive
          ((tuple 'become func)
           (funcall func))))

or:

      (defun universal-server ()
        (receive
          (`#(become ,func)
            (funcall func))))

Examples[edit]

Erlang interoperability[edit]

Calls to Erlang functions take the form (<module>:<function> <arg1> ... <argn>):

(io:format "Hello, World!")

Functional paradigm[edit]

Using recursion to define the Ackermann function:

(defun ackermann
  ((0 n) (+ n 1))
  ((m 0) (ackermann (- m 1) 1))
  ((m n) (ackermann (- m 1) (ackermann m (- n 1)))))

Composing functions:

(defun compose (f g)
  (lambda (x)
   (funcall f
     (funcall g x))))

(defun check ()
  (let* ((sin-asin (compose #'sin/1 #'asin/1))
         (expected (sin (asin 0.5)))
         (compose-result (funcall sin-asin 0.5)))
    (io:format "Expected answer: ~p~n" (list expected))
    (io:format "Answer with compose: ~p~n" (list compose-result))))

Concurrency[edit]

Message-passing with Erlang's light-weight "processes":

(defmodule messenger-back
 (export (print-result 0) (send-message 2)))

(defun print-result ()
  (receive
    ((tuple pid msg)
      (io:format "Received message: '~s'~n" (list msg))
      (io:format "Sending message to process ~p ...~n" (list pid))
      (! pid (tuple msg))
      (print-result))))

(defun send-message (calling-pid msg)
  (let ((spawned-pid (spawn 'messenger-back 'print-result ())))
    (! spawned-pid (tuple calling-pid msg))))

Multiple simultaneous HTTP requests:

(defun parse-args (flag)
  "Given one or more command-line arguments, extract the passed values.

  For example, if the following was passed via the command line:

    $ erl -my-flag my-value-1 -my-flag my-value-2

  One could then extract it in an LFE program by calling this function:

    (let ((args (parse-args 'my-flag)))
      ...
      )
  In this example, the value assigned to the arg variable would be a list
  containing the values my-value-1 and my-value-2."
  (let ((`#(ok ,data) (init:get_argument flag)))
    (lists:merge data)))

(defun get-pages ()
  "With no argument, assume 'url parameter was passed via command line."
  (let ((urls (parse-args 'url)))
    (get-pages urls)))

(defun get-pages (urls)
  "Start inets and make (potentially many) HTTP requests."
  (inets:start)
  (plists:map
    (lambda (x)
      (get-page x)) urls))

(defun get-page (url)
  "Make a single HTTP request."
  (let* ((method 'get)
         (headers '())
         (request-data `#(,url ,headers))
         (http-options ())
         (request-options '(#(sync false))))
    (httpc:request method request-data http-options request-options)
    (receive
      (`#(http #(,request-id #(error ,reason)))
       (io:format "Error: ~p~n" `(,reason)))
      (`#(http #(,request-id ,result))
       (io:format "Result: ~p~n" `(,result))))))

References[edit]

  1. ^ "Lisp Flavored Erlang" (PDF). Robert Virding. Retrieved 2014-01-17. 
  2. ^ a b c "LFE History on the Lisp Flavored Erlang mail list". Retrieved 2014-05-28. 
  3. ^ "LFE announcement on Erlang Questions mail list". Retrieved 2014-01-17. 
  4. ^ a b Armstrong, Joe; Virding, Robert (2013-12-30). "Hardware used in the development of Erlang and LFE" (Email exchange). Interview with Duncan McGreggor. Retrieved 2014-01-17. 
  5. ^ "Follow-up to LFE announcement on Erlang Questions mail list". Retrieved 2014-01-17. 

External links[edit]