File:JuliaRay3.png
Page contents not supported in other languages.
Appearance
![File:JuliaRay3.png](http://upload.wikimedia.org/wikipedia/commons/thumb/1/18/JuliaRay3.png/600px-JuliaRay3.png)
Size of this preview: 600 × 600 pixels. Other resolutions: 240 × 240 pixels | 480 × 480 pixels | 768 × 768 pixels | 1,024 × 1,024 pixels | 1,500 × 1,500 pixels.
Original file (1,500 × 1,500 pixels, file size: 208 KB, MIME type: image/png)
![]() | This is a file from the Wikimedia Commons. Information from its description page there is shown below. Commons is a freely licensed media file repository. You can help. |
Contents
Summary
DescriptionJuliaRay3.png |
English: Julia set and external rays landing on fixed point
Polski: Zbiór Julia i zewnętrzne promienie lądujące na punkcie stałym |
Date | |
Source |
Own work with help of many great people (see references) ![]() This plot was created with Gnuplot by n. |
Author | Adam majewski |
Other versions |
|
![]() |
File:Julia set with 3 external rays.svg is a vector version of this file. It should be used in place of this PNG file when not inferior.
File:JuliaRay3.png → File:Julia set with 3 external rays.svg
For more information, see Help:SVG.
|
What program does ?
Program draws to png file :
- repelling fixed point
and other fixed point
- superattracting 3-point cycle (limit cycle) :
( period is 3 )
- Julia set ( backward orbit of repelling fixed point
) using modified inverse iteration method (MIIM/J)
- 3 external rays :
which land on fixed point
Algorithms
- drawing Julia set
- drawing external ray is based on c program by Curtis McMullen[1] and its Pascal version by Matjaz Erat[2]
Software needed
- Maxima CAS
- gnuplot for drawing ( creates png file )
Tested on versions :
- wxMaxima 0.7.6
- Maxima 5.16.3
- Lisp GNU Common Lisp (GCL) GCL 2.6.8 (aka GCL)
- Gnuplot Version 4.2 patchlevel 3
Source code
It is a batch file for Maxima CAS.
/*
batch file for Maxima CAS
*/
/* --------------------------definitions of functions ------------------------------*/
f(z,c):=z*z+c;
finverseplus(z,c):=sqrt(z-c);
finverseminus(z,c):=-sqrt(z-c);
/*
Square root of complex number : csqrt(x + y * i) = sqrt((r + x) / 2) + i * y / sqrt(2 * (r + x))
gives principal value of square root : -Pi <arg<Pi
*/
csqrt(z):=
block(
[t,re,im],
t:abs(z)+realpart(z),
if t>0
then (re:sqrt(t/2), im:imagpart(z)/sqrt(2*t))
else (im:abs(z), re:0),
return(float(re+im*%i))
)$
Psi_n(r,t,z_last, Max_R):=
/* */
block(
[iMax:200,
iMax2:0],
/* ----- forward iteration of 2 points : z_last and w --------------*/
array(forward,iMax-1), /* forward orbit of z_last for comparison */
forward[0]:z_last,
i:0,
while cabs(forward[i])<Max_R and i< ( iMax-2) do
(
/* forward iteration of z in fc plane & save it to forward array */
forward[i+1]:forward[i]*forward[i] + c, /* z*z+c */
/* forward iteration of w in f0 plane : w(n+1):=wn^2 */
r:r*2, /* square radius = R^2=2^(2*r) because R=2^r */
t:mod(2*t,1),
/* */
iMax2:iMax2+1,
i:i+1
),
/* compute last w point ; it is equal to z-point */
R:2^r,
/* w:R*exp(2*%pi*%i*t), z:w, */
array(backward,iMax-1),
backward[iMax2]:rectform(ev(R*exp(2*%pi*%i*t))), /* use last w as a starting point for backward iteration to new z */
/* ----- backward iteration point z=w in fc plane --------------*/
for i:iMax2 step -1 thru 1 do
(
temp:csqrt(backward[i]-c), /* sqrt(z-c) */
scalar_product:realpart(temp)*realpart(forward[i-1])+imagpart(temp)*imagpart(forward[i-1]),
if (0>scalar_product) then temp:-temp, /* choose preimage */
backward[i-1]:temp
),
return(backward[0])
)$
/*
draws external dynamic rays
R(t) = {z:arg_e(z)=t}
using
z= Psi_n(w) = fc^{-n}(w^2^n)
there are 2 dynamic planes :
- f0 plane where are w points; f0(w):=w*w
- fc plane where are z points; fc(z):=z*z+c
*/
GiveRay(t,c):=
block(
[r],
/* range for drawing R=2^r ; as r tends to 0 R tends to 1 */
rMin:1E-10, /* 1E-4; rMin > 0 ; if rMin=0 then program has infinity loop !!!!! */
rMax:2,
caution:0.9330329915368074, /* r:r*caution ; it gives smaller r */
/* upper limit for iteration */
R_max:300,
/* */
zz:[], /* array for z points of ray in fc plane */
/* some w-points of external ray in f0 plane */
r:rMax,
while 2^r<R_max do r:2*r, /* find point w on ray near infinity (R>=R_max) in f0 plane */
R:2^r,
w:rectform(ev(R*exp(2*%pi*%i*t))),
z:w, /* near infinity z=w */
zz:cons(z,zz),
unless r<rMin do
( /* new smaller R */
r:r*caution,
R:2^r,
/* */
w:rectform(ev(R*exp(2*%pi*%i*t))),
/* */
last_z:z,
z:Psi_n(r,t,last_z,R_max), /* z=Psi_n(w) */
zz:cons(z,zz)
),
return(zz)
)$
/* Gives points of backward orbit of z=repellor */
GiveBackwardOrbit(c,repellor,zxMin,zxMax,zyMin,zyMax,iXmax,iYmax):=
block(
hit_limit:4, /* proportional to number of details and time of drawing */
PixelWidth:(zxMax-zxMin)/iXmax,
PixelHeight:(zyMax-zyMin)/iYmax,
/* 2D array of hits pixels . Hit > 0 means that point was in orbit */
array(Hits,fixnum,iXmax,iYmax), /* no hits for beginning */
/* choose repeller z=repellor as a starting point */
stack:[repellor], /*save repellor in stack */
/* save first point to list of pixels */
x_y:[repellor],
/* reversed iteration of repellor */
loop,
/* pop = take one point from the stack */
z:last(stack),
stack:delete(z,stack),
/*inverse iteration - first preimage (root) */
z:finverseplus(z,c),
/* translate from world to screen coordinate */
iX:fix((realpart(z)-zxMin)/PixelWidth),
iY:fix((imagpart(z)-zyMin)/PixelHeight),
hit:Hits[iX,iY],
if hit<hit_limit
then
(
Hits[iX,iY]:hit+1,
stack:endcons(z,stack), /* push = add z at the end of list stack */
if hit=0 then x_y:endcons( z,x_y)
),
/*inverse iteration - second preimage (root) */
z:-z,
/* translate from world to screen coordinate, coversion to integer */
iX:fix((realpart(z)-zxMin)/PixelWidth),
iY:fix((imagpart(z)-zyMin)/PixelHeight),
hit:Hits[iX,iY],
if hit<hit_limit
then
(
Hits[iX,iY]:hit+1,
stack:endcons(z,stack), /* push = add z at the end of list stack to continue iteration */
if hit=0 then x_y:endcons( z,x_y)
),
if is(not emptyp(stack)) then go(loop),
return(x_y) /* list of pixels in the form [z1,z2] */
)$
compile(all);
/* ----------------------- main ----------------------------------------------------*/
start:elapsed_run_time ();
/* c:-0.12256+0.74486*%i; value by Milnor*/
c:0.74486176661974*%i-0.12256116687665; /* center of period 3 component */
/* resolution is proportional to number of details and time of drawing */
iX_max:5000;
iY_max:5000;
/* define z-plane ( dynamical ) */
ZxMin:-2.0;
ZxMax:2.0;
ZyMin:-2.0;
ZyMax:2.0;
/* compute ray points & save to zz list; external angle in turns */
zz1:GiveRay(1/7,c)$
zz2:GiveRay(2/7,c)$
zz4:GiveRay(4/7,c)$
/* limit cycle */
z0:0;
zp:[];
zp:cons(z0,zp);
z1:f(z0,c);
zp:cons(z1,zp);
z2:f(z1,c);
zp:cons(z2,zp);
/* compute fixed points */
beta:rectform((1+csqrt(1-4*c))/2); /* compute repelling fixed point beta */
alfa:rectform((1-csqrt(1-4*c))/2); /* other fixed point */
/* compute backward orbit of repelling fixed point */
xy: GiveBackwardOrbit(c,beta,ZxMin,ZxMax,ZyMin,ZyMax,iX_max,iY_max)$ /**/
/* time of computations */
time:fix(elapsed_run_time ()-start);
/* draw it using draw package by */
load(draw);
draw2d(
terminal = 'svg,
file_name = "~/maxima/batch/julia/rabbit/JuliaRay151",
user_preamble="set size square;set key bottom right",
title= concat("Dynamical plane for fc(z)=z*z+",string(c),"; Julia set and external
rays landing on fixed point z=alfa"),
pic_width = 1500,
pic_height = 1500,
yrange = [ZyMin,ZyMax],
xrange = [ZxMin,ZyMax],
xlabel = "Z.re ",
ylabel = "Z.im",
point_type = filled_circle,
points_joined =true,
point_size = 0.1,
color = red,
key = concat("external ray for angle ",string(1/7)),
points(map(realpart,zz1),map(imagpart,zz1)),
key = concat("external ray for angle ",string(2/7)),
points(map(realpart,zz2),map(imagpart,zz2)),
key = concat("external ray for angle ",string(4/7)),
points(map(realpart,zz4),map(imagpart,zz4)),
points_joined =false,
color = black,
key = "backward orbit of z=beta",
points(map(realpart,xy),map(imagpart,xy)),
color = blue,
point_size = 0.9,
key = "repelling fixed point z= beta",
points([[realpart(beta),imagpart(beta)]]),
color = yellow,
key = "repelling fixed point z= alfa",
points([[realpart(alfa),imagpart(alfa)]]),
color = green,
key = "periodic z-points",
points(map(realpart,zp),map(imagpart,zp))
);
Acknowledgements
This program is not only my work but was done with help of many great people (see references). Warm thanks (:-))
References
- ↑ c program by Curtis McMullen (quad.c in Julia.tar.gz) archive copy at the Wayback Machine
- ↑ Quadratische Polynome by Matjaz Erat
Licensing
I, the copyright holder of this work, hereby publish it under the following licenses:
![w:en:Creative Commons](https://upload.wikimedia.org/wikipedia/commons/thumb/7/79/CC_some_rights_reserved.svg/90px-CC_some_rights_reserved.svg.png)
![attribution](https://upload.wikimedia.org/wikipedia/commons/thumb/1/11/Cc-by_new_white.svg/24px-Cc-by_new_white.svg.png)
![share alike](https://upload.wikimedia.org/wikipedia/commons/thumb/d/df/Cc-sa_white.svg/24px-Cc-sa_white.svg.png)
This file is licensed under the Creative Commons Attribution-Share Alike 3.0 Unported license.
- You are free:
- to share – to copy, distribute and transmit the work
- to remix – to adapt the work
- Under the following conditions:
- attribution – You must give appropriate credit, provide a link to the license, and indicate if changes were made. You may do so in any reasonable manner, but not in any way that suggests the licensor endorses you or your use.
- share alike – If you remix, transform, or build upon the material, you must distribute your contributions under the same or compatible license as the original.
![]() |
Permission is granted to copy, distribute and/or modify this document under the terms of the GNU Free Documentation License, Version 1.2 or any later version published by the Free Software Foundation; with no Invariant Sections, no Front-Cover Texts, and no Back-Cover Texts. A copy of the license is included in the section entitled GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue |
You may select the license of your choice.
Captions
Add a one-line explanation of what this file represents
Items portrayed in this file
depicts
some value
23 May 2009
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 20:15, 26 June 2015 | ![]() | 1,500 × 1,500 (208 KB) | Soul windsurfer | better quality |
15:51, 25 May 2009 | ![]() | 1,000 × 1,000 (18 KB) | Soul windsurfer | changed bad names ( beta instead of alfa ) | |
09:14, 23 May 2009 | ![]() | 1,000 × 1,000 (18 KB) | Soul windsurfer | {{Information |Description={{en|1=Julia set and external rays landing on repelling fixed point. Parametr c is in the center of period 3 hyperbolic component of Mandelbrot set}} {{pl|1=Zbiór Julia i zewnętrzne promienie lądujące na odpychającym punkci |
File usage
The following pages on the English Wikipedia use this file (pages on other projects are not listed):
Global file usage
The following other wikis use this file:
- Usage on el.wikipedia.org
- Usage on en.wikibooks.org
Retrieved from "https://en.wikipedia.org/wiki/File:JuliaRay3.png"