File:Luneburg Lens.gif
Page contents not supported in other languages.
Appearance
Luneburg_Lens.gif (360 × 408 pixels, file size: 4 MB, MIME type: image/gif, looped, 53 frames, 5.3 s)
![]() | This is a file from the Wikimedia Commons. Information from its description page there is shown below. Commons is a freely licensed media file repository. You can help. |
Summary
DescriptionLuneburg Lens.gif |
English: A Luneburg lens has a gradually varying refractive index, such that a point source on its edge will be converted into a plane wave (and vice-versa, a plane wave will be focussed on its edge). |
Date | |
Source | https://twitter.com/j_bertolotti/status/1394635354209230849 |
Author | Jacopo Bertolotti |
Permission (Reusing this file) |
https://twitter.com/j_bertolotti/status/1030470604418428929 |
Mathematica 12.0 code
\[Lambda]0 = 1.; k0 = N[(2 \[Pi])/\[Lambda]0]; (*The wavelength in vacuum is set to 1, so all lengths are now in units of wavelengths*)
\[Delta] = \[Lambda]0/20; \[CapitalDelta] = 40*\[Lambda]0; (*Parameters for the grid*)
ReMapC[x_] := RGBColor[(2 x - 1) UnitStep[x - 0.5], 0, (1 - 2 x) UnitStep[0.5 - x]];
R = \[CapitalDelta]/3;
ren = Table[
If[x^2 + y^2 <= R^2, Sqrt[2 - ((x^2 + y^2)/R^2)], 1], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];
d = \[Lambda]0/2; (*typical scale of the absorbing layer*)
imn = Table[
Chop[5 (E^-((x + \[CapitalDelta]/2)/d) + E^((x - \[CapitalDelta]/2)/d) + E^-((y + \[CapitalDelta]/2)/d) + E^((y - \[CapitalDelta]/2)/d))], {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}]; (*Imaginary part of the refractive index (used to emulate absorbing boundaries)*)
dim = Dimensions[ren][[1]];
L = -1/\[Delta]^2*KirchhoffMatrix[GridGraph[{dim, dim}]]; (*Discretized Laplacian*)
n = ren + I imn;
sinstep[t_] := 20 - (5/6 \[CapitalDelta]) Sin[\[Pi]/2 t]^2;
frames1 = Table[
\[Phi]in = Table[E^(-((x)^2 + (y + sinstep[t])^2)/(2 (\[Lambda]0/5)^2)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
MatrixPlot[Transpose[(Re[(\[Phi]in + \[Phi]s)]/Max[Abs@Re[\[Phi]in + \[Phi]s][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> ReMapC, DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, PlotLabel -> "Luneburg Lens: n=\!\(\*SqrtBox[\(2 - \*FractionBox[SuperscriptBox[\(r\), \(2\)], SuperscriptBox[\(R\), \(2\)]]\)]\)", LabelStyle -> {Black, Bold}, Epilog -> {White, Circle[{Round[dim/2 - (4 d)/\[Delta]], Round[dim/2 - (4 d)/\[Delta]]}, dim/3 - (1 d)/\[Delta]]}](*Plot everything*)
, {t, 0, 1, 1/20}];
sinstep[t_] := 20 - (5/6 \[CapitalDelta]) Sin[\[Pi]/2 t]^2;
frames2 = Table[
\[Phi]in = Table[E^(-((x - \[CapitalDelta]/3 Cos[\[Theta]])^2 + (y - \[CapitalDelta]/3 Sin[\[Theta]])^2)/(2 (\[Lambda]0/5)^2)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
MatrixPlot[Transpose[(Re[(\[Phi]in + \[Phi]s)]/Max[Abs@Re[\[Phi]in + \[Phi]s][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> ReMapC, DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, PlotLabel -> "Luneburg Lens: n=\!\(\*SqrtBox[\(2 - \*FractionBox[SuperscriptBox[\(r\), \(2\)], SuperscriptBox[\(R\), \(2\)]]\)]\)", LabelStyle -> {Black, Bold}, Epilog -> {White, Circle[{Round[dim/2 - (4 d)/\[Delta]], Round[dim/2 - (4 d)/\[Delta]]}, dim/3 - (1 d)/\[Delta]]}](*Plot everything*)
, {\[Theta], \[Pi]/2, 3/2 \[Pi], \[Pi]/20}];
sinstep[t_] := 1/3 \[CapitalDelta] + (\[CapitalDelta]/2 - \[CapitalDelta]/3) Sin[\[Pi]/2 t]^2;
frames3 = Table[
\[Phi]in = Table[E^(-((x)^2 + (y + sinstep[t])^2)/(2 (\[Lambda]0/5)^2)), {x, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}, {y, -\[CapitalDelta]/2, \[CapitalDelta]/2, \[Delta]}];(*Discretized source*)
b = -(Flatten[n]^2 - 1) k0^2 Flatten[\[Phi]in]; (*Right-hand side of the equation we want to solve*)
M = L + DiagonalMatrix[SparseArray[Flatten[n]^2 k0^2]]; (*Operator on the left-hand side of the equation we want to solve*)
\[Phi]s = Partition[LinearSolve[M, b], dim]; (*Solve the linear system*)
MatrixPlot[ Transpose[(Re[(\[Phi]in + \[Phi]s)]/Max[Abs@Re[\[Phi]in + \[Phi]s][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]]])][[(4 d)/\[Delta] ;; (-4 d)/\[Delta], (4 d)/\[Delta] ;; (-4 d)/\[Delta]]], ColorFunction -> ReMapC, DataReversed -> True, Frame -> False, PlotRange -> {-1, 1}, PlotLabel -> "Luneburg Lens: n=\!\(\*SqrtBox[\(2 - \*FractionBox[SuperscriptBox[\(r\), \(2\)], SuperscriptBox[\(R\), \(2\)]]\)]\)", LabelStyle -> {Black, Bold}, Epilog -> {White, Circle[{Round[dim/2 - (4 d)/\[Delta]], Round[dim/2 - (4 d)/\[Delta]]}, dim/3 - (1 d)/\[Delta]]}](*Plot everything*)
, {t, 0, 1, 1/10}];
ListAnimate[Join[frames1, frames2, frames3]]
Licensing
I, the copyright holder of this work, hereby publish it under the following license:
![]() ![]() |
This file is made available under the Creative Commons CC0 1.0 Universal Public Domain Dedication. |
The person who associated a work with this deed has dedicated the work to the public domain by waiving all of their rights to the work worldwide under copyright law, including all related and neighboring rights, to the extent allowed by law. You can copy, modify, distribute and perform the work, even for commercial purposes, all without asking permission.
http://creativecommons.org/publicdomain/zero/1.0/deed.enCC0Creative Commons Zero, Public Domain Dedicationfalsefalse |
Captions
Luneburg lens illuminated with a point source at varying positions.
Items portrayed in this file
depicts
18 May 2021
File history
Click on a date/time to view the file as it appeared at that time.
Date/Time | Thumbnail | Dimensions | User | Comment | |
---|---|---|---|---|---|
current | 08:05, 19 May 2021 | ![]() | 360 × 408 (4 MB) | Berto | Uploaded own work with UploadWizard |
File usage
The following pages on the English Wikipedia use this file (pages on other projects are not listed):
Metadata
This file contains additional information, probably added from the digital camera or scanner used to create or digitize it.
If the file has been modified from its original state, some details may not fully reflect the modified file.
GIF file comment | Created with the Wolfram Language : www.wolfram.com |
---|
Retrieved from "https://en.wikipedia.org/wiki/File:Luneburg_Lens.gif"