Rexx

REXX

Paradigm	multiparadigm: procedural, structured
Designed by	Mike Cowlishaw
Developer	Mike Cowlishaw, IBM
First appeared	1979 (1979)
Stable release	ANSI X3.274 / 1996 (1996)
Typing discipline	dynamic, everything is a string (Classic REXX) or object (Object REXX)
Major implementations
VM/SP and later, TSO/E V2 and later, IBM NetRexx, Object REXX, Open Object Rexx, Regina, others
Dialects
Object REXX, Open Object Rexx, NetRexx
Influenced by
PL/I, Algol, EXEC 2
Influenced
NetRexx, Object REXX, Open Object Rexx

REXX (REstructured eXtended eXecutor) is an interpreted programming language that was developed at IBM. It is a structured high-level programming language that was designed to be both easy to learn and easy to read. Both proprietary and open source interpreters for REXX are available on a wide range of computing platforms, and compilers are available for IBM mainframes.

Rexx is widely used as a glue language, macro language, and is often used for processing data and text and generating reports; these similarities with Perl mean that Rexx works well in Common Gateway Interface (CGI) programming and it is indeed used for this purpose. Rexx is the primary scripting language in some operating systems, e.g. OS/2, MVS, VM, AmigaOS, and is also used as an internal macro language in some other software, e.g., KEDIT, THE, the ZOC terminal emulator. Additionally, the Rexx language can be used for scripting and macros in any program that uses Windows Scripting Host ActiveX scripting engines languages (e.g. VBScript and JScript) if one of the Rexx engines (see below) are installed.

Rexx is supplied with VM/SP on up, TSO/E Version 2 on up, OS/2 (1.3 on up), PC DOS (7.0 or 2000), and Windows NT 4.0 (Resource Kit: Regina). REXX scripts for OS/2 and NT-based Windows have the filename extension .cmd and the first line of the script determines the operating system the script is for.

Features

REXX has the following characteristics and features:

• simple syntax
• small instruction set containing just two dozen instructions
• freeform syntax
• case insensitive tokens, including variable names
• character string basis
• dynamic data typing, no declarations
• no reserved keywords, except in local context
• arbitrary numerical precision
• decimal arithmetic, floating-point
• a rich selection of built-in functions, especially string and word processing
• automatic storage management
• crash protection
• content addressable data structures
• associative arrays
• straightforward access to system commands and facilities
• simple error-handling, and built-in tracing and debugger
• few artificial limitations
• simplified I/O facilities
• unconventional operators
• only partly supports Unix style command line parameters, except specific implementations
• provides no basic terminal control as part of the language, except specific implementations
• provides no generic way to include functions and subroutines from external libraries, except specific implementations

REXX has just twenty-three, largely self-evident, instructions (e.g., call, parse, and select) with minimal punctuation and formatting requirements. It is essentially an almost free-form language with only one data-type, the character string; this philosophy means that all data are visible (symbolic) and debugging and tracing are simplified.

REXX syntax looks similar to PL/I, but has fewer notations; this makes it harder to parse (by program) but easier to use, except for cases where PL/I habits may lead to surprises.

History

REXX was designed and first implemented, in assembly language, as an ‘own-time’ project between 20 March 1979 and mid-1982 by Mike Cowlishaw of IBM, originally as a scripting programming language to replace the languages EXEC and EXEC 2. It was designed to be a macro or scripting language for any system. As such, REXX is considered a precursor to Tcl and Python. REXX was also intended by its creator to be a simplified and easier to learn version of the PL/I programming language. However, some differences from PL/I may trip up the unwary.

It was first described in public at the SHARE 56 conference in Houston, Texas, in 1981, where customer reaction, championed by Ted Johnston of SLAC, led to it being shipped as an IBM product in 1982.

Over the years IBM included REXX in almost all of its operating systems (VM/CMS, VM/GCS, MVS TSO/E, AS/400, VSE/ESA, AIX, CICS/ESA, PC DOS, and OS/2), and has made versions available for Novell NetWare, Windows, Java, and Linux.

The first non-IBM version was written for PC DOS by Charles Daney in 1984/5. The first compiler version appeared in 1987, written for CMS by Lundin and Woodruff. Other versions have also been developed for Atari, AmigaOS, Unix (many variants), Solaris, DEC, Windows, Windows CE, Pocket PC, DOS, Palm OS, QNX, OS/2, Linux, BeOS, EPOC32, AtheOS, OpenVMS, OpenEdition, Apple Macintosh, and Mac OS X.

The Amiga version of REXX, called ARexx was included with AmigaOS 2 onwards and was popular for scripting as well as application control. Many Amiga applications have an "ARexx port" built into them which allows control of the application from Rexx. One single Rexx script could even switch between different Rexx ports in order to control several running applications.

Several freeware versions of REXX are available. In 1992, the two most widely-used open-source ports appeared: Ian Collier's REXX/imc for Unix and Anders Christensen's Regina (later adopted by Mark Hessling) for Windows and Linux. BREXX is well-known for WinCE and Pocket PC platforms.

OS/2 had a visual development system from Watcom VX-REXX another dialect was VisPro REXX from Hockware.

In 1996 American National Standards Institute (ANSI) published a standard for REXX: ANSI X3.274–1996 “Information Technology – Programming Language REXX”. More than two dozen books on REXX have been published since 1985.

Since the mid-1990s, two newer variants of REXX have appeared:

• NetRexx — which compiles to Java byte-code via Java source code; this has no reserved keywords at all, and uses the Java object model, and is therefore not generally upwards-compatible with ‘classic’ REXX.
• Object REXX — which is an object-oriented generally upwards-compatible version of REXX.

In 1990, Cathy Dager of SLAC organized the first independent REXX symposium, which led to the forming of the REXX Language Association. Symposia are held annually.

REXX marked its 25^th anniversary on 20 March 2004, which was celebrated at the REXX Language Association’s 15^th International REXX Symposium in Böblingen, Germany, in May 2004.

On October 12, 2004, IBM announced their plan to release their Object REXX implementation's sources under the Common Public License. Recent releases of Object REXX contain a ActiveX WSH scripting engine implementing this version of the Rexx language.

On February 22, 2005, the first public release of Open Object Rexx (ooRexx) was announced. This product contains a WSH scripting engine which allows for programming of the Windows operating system and applications with Rexx in the same fashion in which Visual Basic and Java/J++ are implemented by the default WSH installation and Perl, Tcl, Python third-party scripting engines. The default filename extension for ooRexxScript scripts is *.rxs.

A command-line Rexx interpreter is also installed with ooRexx, and it is also possible to run ooRexxScript programs from the command line by means of the CScript command (WScript may also be run from the command line) invoking the Windows Scripting Host.

A Rexx IDE, RxxxEd, has been developed for Windows. RxSock for network communication as well as other add-ons to and implementations of Regina Rexx have been developed, and a Rexx interpreter for the Windows command line is supplied in most Resource Kits for various versions of Windows and works under all of them as well as MS-DOS.

Portable Rexx by Kilowatt and Personal Rexx by Quercus are two Rexx interpreters designed for MS-DOS and can of course be run under Windows as well using a command prompt.

Spelling, capitalizing

Originally it was just called "Rex", "A Reformed EXecutor"; the extra "X" was added to avoid collisions with other products' names. The expansion of Rexx to the REstructured EXtended EXecutor is believed to be a backronym. REX was originally all uppercase because the mainframe code was uppercase oriented. The style in those days was to have all-caps names, partly because almost all code was still all-caps then. For the product it became REXX, and both editions of Mike Cowlishaw's book use all-caps. By the 1990s it was largely written Rexx or, with small caps: REXX. As of 2008, Mike Cowlishaw seems to prefer Rexx, IBM documents use REXX, and the ANSI standard uses REXX.

Syntax

Looping

The loop control structure in REXX begins with a DO and ends with an END but comes in several varieties. NetRexx uses the keyword LOOP instead of DO for looping, while ooRexx treats LOOP and DO as equivalent when looping.

Traditional forms:

   do expression [count]
     [instructions]
   end

   do until [condition]
     [instructions]
   end

   do while [condition]
     [instructions]
   end

With an index variable:

   do i = x [to y ] [by z]
     [instructions]
   end

another variant:

   do i = x [by z ] [to y] [for k]
     [instructions]
   end

The step increment (z above) may be omitted and defaults to 1. The upper limit (y above) can also be omitted, which makes the loop continue forever. You can also loop forever without an index variable with this:

   do forever
     [instructions]
   end

A program can break out of the current loop with the leave instruction (which is the normal way to exit a "forever" loop), or can short-circuit it with the iterate instruction.

The do while and do until forms are equivalent to:

  do forever
    if [condition] then leave                /*similar to WHILE*/
    [instructions]
  end

and:

  do forever
    [instructions]
    if [condition] then leave                /*similar to UNTIL*/  
  end

Conditionals

Testing conditions with IF

   if [condition] then
     do
       [instructions]
     end
   else
     do
       [instructions]
     end

Note that the ELSE clause is optional.

Or, to put it more concisely:

   if [condition] then  do
                        [instructions]
                        end
                  else  do
                        [instructions]
                        end

For single instructions, DO and END can also be omitted:

   if [condition] then
     [instruction]
   else
     [instruction]

Or, in another concise version:

   if [condition] then   [instruction]
                  else   [instruction]

Indentation is optional, but it helps improve the readbility.

Testing for multiple conditions

SELECT is REXX's CASE structure, like many other constructs derived from PL/I:

   select
     when [condition] then
         [instruction]
     when [condition] then
       do
         [instructions]
       end
     otherwise
       [instructions] or NOP
   end

NOP indicates no instruction is to be executed.

Note that the OTHERWISE clause is optional. If omitted and no WHEN conditions are met, then the SYNTAX condition is raised.

Simple variables

Variables in REXX are typeless, and initially are evaluated as their names, in upper case. Thus a variable's type can vary with its use in the program:

 say hello             /* =>  HELLO      */
 hello = 25
 say hello             /* =>  25         */
 hello = "say 5 + 3"
 say hello             /* =>  say 5 + 3  */
 interpret hello       /* =>  8          */
 drop hello
 say hello             /* =>  HELLO      */

Compound variables

Unlike many other programming languages, classic REXX has no direct support for arrays of variables addressed by a numerical index. Instead it provides compound variables. A compound variable consists of a stem followed by a tail. A . (dot) is used to join the stem to the tail. If the tails used are numeric, it is easy to produce the same effect as an array.

 do i = 1 to 10
   stem.i = 10 - i
 end

Afterwards the following variables with the following values exist: stem.1 = 9, stem.2 = 8, stem.3 = 7...

Unlike arrays, the index for a stem variable is not required to have an integer value. For example, the following code is valid:

 i = 'Monday'
 stem.i = 2

In REXX it is also possible to set a default value for a stem.

 stem. = 'Unknown'
 stem.1 = 'USA'
 stem.44 = 'UK'
 stem.33 = 'France'

After these assignments the term stem.3 would produce 'Unknown'.

The whole stem can also be erased with the DROP statement.

 drop stem.

This also has the effect of removing any default value set previously.

By convention (and not as part of the language) the compound stem.0 is often used to keep track of how many items are in a stem, for example a procedure to add a word to a list might be coded like this:

 add_word: procedure expose dictionary.
   parse arg w
   n = dictionary.0 + 1
   dictionary.n = w
   dictionary.0 = n
   return

It is also possible to have multiple elements in the tail of a compound variable. For example:

 m = 'July'
 d = 15
 y = 2005
 day.y.m.d = 'Friday'

Multiple numerical tail elements can be used to provide the effect of a multi-dimensional array.

Features similar to REXX compound variables are found in many other languages (associative arrays in AWK, hashes in Perl, Hashtables in Java, etc). Most of these languages provide an instruction to iterate over all the keys (or tails in REXX terms) of such a construct, but this is lacking in classic REXX. Instead it is necessary to keep auxiliary lists of tail values as appropriate. For example in a program to count words the following procedure might be used to record each occurrence of a word.

 add_word: procedure expose count. word_list
   parse arg w .
   count.w = count.w + 1 /* assume count. has been set to 0 */
   if count.w = 1 then word_list = word_list w
   return

and then later

 do i = 1 to words(word_list)
   w = word(word_list,i)
   say w count.w
 end

At the cost of some clarity it is possible to combine these techniques into a single stem.

 add_word: procedure expose dictionary.
   parse arg w .
   dictionary.w = dictionary.w + 1
   if dictionary.w = 1 /* assume dictionary. = 0 */
     then do
       n = dictionary.0+1
       dictionary.n = w
       dictionary.0 = n
     end
   return

and later

 do i = 1 to dictionary.0
   w = dictionary.i
   say i w dictionary.w
 end

However, REXX provides no safety net here, so if one of your words happens to be a whole number less than dictionary.0 the above technique will fail mysteriously.

Recent implementations of REXX, including IBM's Object REXX and the open source implementations like ooRexx include a new language construct to simplify iteration over the value of a stem, or over another collection object such as an array, table, list, etc.

 do i over stem.
   say i '-->' stem.i
 end

Keyword instructions

PARSE

The PARSE instruction is particularly powerful; it combines some useful string-handling functions. Its syntax is:

   parse [upper] origin [template]

where origin specifies the source:

• arg (arguments, at top level tail of command line)
• linein (standard input, e.g. keyboard)
• pull (REXX data queue or standard input)
• source (info on how program was executed)
• value (an expression) with

  the keyword with is required to indicate where the expression ends

• var (a variable)
• version (version/release number)

and template can be:

• list of variables
• column number delimiters
• literal delimiters

upper is optional; if specified, data will be converted to upper case before parsing.

Examples:

Using a list of variables as template

   myVar = "John Smith"
   parse var myVar firstName lastName
   say "First name is:" firstName
   say "Last name is:"  lastName

displays the following:

   First name is: John
   Last name is: Smith

Using a delimiter as template:

   myVar = "Smith, John"
   parse var myVar LastName "," FirstName
   say "First name is:" firstName
   say "Last name is:"  lastName

also displays the following:

   First name is: John
   Last name is: Smith

Using column number delimiters:

   myVar = "(202) 123-1234"
   parse var MyVar 2 AreaCode 5  7 SubNumber
   say "Area code is:" AreaCode
   say "Subscriber number is:" SubNumber

displays the following:

   Area code is: 202
   Subscriber number is: 123-1234

A template can use a combination of variables, literal delimiters, and column number delimiters.

INTERPRET

The INTERPRET instruction evaluates its argument and treats its value as a REXX statement. Sometimes INTERPRET is the clearest way to perform a task, but it is often used where clearer code is possible using, e.g., value().

 /* a touch of LISP */
 X = 'square'
 interpret 'say' X || '(4) ; exit'
 SQUARE: return arg(1)**2

This displays 16 and exits. Because variable contents in REXX are strings, including rational numbers with exponents and even entire programs, REXX offers to interpret strings as evaluated expressions.

This feature could be used to pass functions as function parameters, such as passing SIN, COS, etc. to a procedure to calculate integrals.

Note that REXX offers only basic math functions like ABS, DIGITS, MAX, MIN, SIGN, RANDOM, and a complete set of hex plus binary conversions with bit operations. More complex functions like SIN had to be implemented from scratch or obtained from third party external libraries. Some external libraries, typically those implemented in traditional languages, did not support extended precision.

Later versions (non-classic) support CALL variable constructs. Together with the built-in function VALUE, CALL can be used in place of many cases of INTERPRET. This is a classic program:

 /* terminated by input "exit" or similar */
 do forever ; interpret linein() ; end

A slightly more sophisticated REXX calculator:

 X = 'input BYE to quit'
 do until X = 'BYE' ; interpret 'say' X ; pull X ; end

PULL is shorthand for parse upper pull

Likewise, ARG is shorthand for parse upper arg

The power of the INTERPRET instruction had other uses. The Valour software package relied upon REXX's interpretive ability to implement an OOP environment. Another use was found in an unreleased Westinghouse product called Time Machine that was able to fully recover following a fatal error.

NUMERIC

  say digits() fuzz() form()          /* => 9 0 SCIENTIFIC */
  say 999999999+1                     /* => 1.000000000E+9 */
  numeric digits 10                   /* only limited by available memory */ 
  say 999999999+1                     /* => 1000000000 */

  say 0.9999999999=1                  /* => 0 (false) */
  numeric fuzz 3
  say 0.99999999=1                    /* => 1 (true) */
  say 0.99999999==1                   /* => 0 (false) */

  say 100*123456789                   /* => 1.23456789E+10 */
  numeric form engineering
  say 100*123456789                   /* => 12.34567890E+9 */

  numeric digits 50
  n=2
  r=1
        do forever                    /* Newton's method */
        rr=(n/r+r)/2
        if r=rr then leave
        r=rr
        end
  say "root" n '=' r                  /*root 2=1.414213562373095048801688724209698078569671875377*/

  numeric digits 50
  e=2.5
  f=0.5  
       do n=3
       f=f/n
       ee=e+f
       if e=ee then leave
       e=ee
       end
  say "e=" e                           /*e=2.7182818284590452353602874713526624977572470936998*/

SIGNAL

The REXX SIGNAL instruction is intended for abnormal changes in the flow of control (see the next section). However, it can be misused and treated like the GOTO statement found in other languages (although it is not strictly equivalent, because it terminates loops and other constructs). This can produce difficult-to-read code.

Error handling and exceptions

It is possible in REXX to intercept and deal with errors and other exceptions, using the SIGNAL instruction. There are seven system conditions: ERROR, FAILURE, HALT, NOVALUE, NOTREADY, LOSTDIGITS and SYNTAX. Handling of each can be switched on and off in the source code as desired.

This example will run until stopped by the user:

On most PCs, halting would be accomplished by pressing the Ctrl-Pause (also called the Break key).

On some mainframe systems, pressing the PA1 key (Program Assist).

 signal on halt;
 do a = 1
   say a
   do 100000 /* a delay */
   end
 end
 halt:
   say "The program was stopped by the user" 
 exit

Virtually all serious REXX programs contain signal on novalue or a similar statement. This disables the "feature", where undefined variables get their own (upper case) name as value. The status of a variable can be checked with the built-in function SYMBOL returning VAR for defined variables.

Function VALUE can be used to get the value of variables without triggering a NOVALUE condition, but its main purpose is to read and set environment variables - similar to POSIX getenv and putenv.

Conditions

ERROR	Positive RC from a system command
FAILURE	Negative RC for a system command (e.g. command doesn't exist)
HALT	Abnormal termination (see above)
NOVALUE	An unset variable was referenced (see above)
NOTREADY	Input or output error (e.g. read attempts beyond end of file)
SYNTAX	Invalid program syntax, or some error condition not covered above
LOSTDIGITS	Significant digits are lost (ANSI REXX, not in TRL second edition)

When a condition is handled by SIGNAL ON, the SIGL and RC system variables can be analyzed to understand the situation. RC contains the REXX error code and SIGL contains the line number where the error arose.

Beginning with REXX version 4 conditions can get names, and there's also a CALL ON construct. That's handy if external functions do not necessarily exist:

  ChangeCodePage: procedure /* protect SIGNAL settings */
    signal on syntax name ChangeCodePage.Trap
    return SysQueryProcessCodePage()
  ChangeCodePage.Trap: return 1004 /* windows-1252 on OS/2 */

See also

• ARexx, the native REXX interpreter of AmigaOS
• ISPF, dialog manager and text editor(s) with native REXX support
• XEDIT, text editor(s) with native REXX support
• NetRexx, a Rexx-like language compiling into Java byte code
• Object REXX, an object-oriented programming language based on the REXX language
• Comparison of computer shells
• Comparison of programming languages

Books

• Callaway, Merrill. The Rexx Cookbook: A Tutorial Guide to the Rexx Language in OS/2 & Warp on the IBM Personal Computer. Whitestone, 1995. ISBN 0-96-327734-0.
• Cowlishaw, Michael. The Rexx Language: A Practical Approach to Programming. Prentice Hall, 1990. ISBN 0-13-780651-5.
• Cowlishaw, Michael. The NetRexx Language. Prentice Hall, 1997. ISBN 0-13-806332-X.
• Daney, Charles. Programming in REXX. McGraw-Hill, TX, 1990. ISBN 0-07-015305-1.
• Deuring, Johannes. REXX Grundlagen für die z/OS Praxis. Germany, 2005. ISBN 3-486-20025-9.
• Ender, Tom. Object-Oriented Programming With Rexx. John Wiley & Sons, 1997. ISBN 0-471-11844-3.
• Fosdick, Howard. Rexx Programmer's Reference. Wiley/Wrox, 2005. ISBN 0-7645-7996-7.
• Gargiulo, Gabriel. REXX with OS/2, TSO, & CMS Features. MVS Training, 1999 (third edition 2004). ISBN 1-892559-03-X.
• Goldberg, Gabriel and Smith, Philip H. The Rexx Handbook . McGraw-Hill, TX, 1992. ISBN 0-07-023682-8.
• Goran, Richard K. REXX Reference Summary Handbook. CFS Nevada, Inc.,1997. ISBN 0-9639854-3-4.
• IBM Redbooks. Implementing Rexx Support in Sdsf. Vervante, 2007. ISBN 0-738-48914-X.
• Kiesel, Peter C. Rexx: Advanced Techniques for Programmers. McGraw-Hill, TX, 1992. ISBN 0-07-034600-3.
• Marco, Lou ISPF/REXX Development for Experienced Programmers. CBM Books, 1995. ISBN 1-878956-50-7
• O'Hara, Robert P. and Gomberg, David Roos. Modern Programming Using Rexx. Prentice Hall, 1988. ISBN 0-13-597329-5.
• Rudd, Anthony S. Practical Usage of Rexx. Ellis Horwood Ltd., 1991. ISBN 0-13682-790-X.
• Schindler, William. Down to Earth Rexx. Perfect Niche Software, 2000. ISBN 0-9677590-0-5.

External links

• Mike Cowlishaw's home page
• REXX language page at IBM
• REXX Language Association
  • RexxLA's list of Rexx books
• REXX Information-- Downloads, tools, tutorials, reference materials, etc.
• The Script Library

Classic interpreters

• Regina: open-source (LGPL) interpreter for Linux, BSD, Windows, etc.
• REXX/imc: source available (non-standard license) interpreter for Unix and Linux systems.
• BREXX: source available (non-commercial) interpreter for Linux, DOS, Windows CE, etc.. (Versions 2.1.3 to 2.1.6 are available under GPL licence (see file COPYING in unpacked tarball.))
• Reginald: free interpreter for Windows.
• roo!: freeware interpreter for Windows with object-oriented extensions from Kilowatt Software.
• r4: freeware interpreter for Windows from Kilowatt Software.
• REXX for Palm OS: shareware interpreter for Palm OS from Jaxo Inc.
• S/REXX: commercial interpreter for UNIX and Windows from Benaroya.
• uni-REXX: commercial interpreter for UNIX from The Workstation Group Ltd.

Other interpreters

• Open Object Rexx web site
• IBM NetREXX web site

Compilers

• IBM Compiler and Library for REXX on zSeries

Software using REXX for scripting

• OS/2
• z/OS
• z/VM
• ISPF and XEDIT clones

Newsgroups

• comp.lang.rexx

Tutorials

• Rexx for everyone: An introduction by David Mertz for IBM developerWorks.
• Vladimir Zabrodsky's Album of Algorithms and Techniques for Standard Rexx
• Vladimir Zabrodsky's An Introduction to the Rexx Programming Language
• PLEAC-REXX: Programming Language Examples Alike Cookbook for REXX
• Tips & tricks 3.60 by Bernd Schemmer (OS/2 INF format, 755 KB ZIP, 2004)
• Rexx Frequently Asked Questions (FAQ)
• Introductory Rexx Tutorial, SHARE, Spring 1997